enum DirStat <CanWrite NoDir NoWrite>;
sub check-dir-status($dir --> DirStat) {
    if $dir.IO.d {
        # dir exists, can the program user write to it? 
        my $f = "$dir/.tmp";
        spurt $f, "some text";
        CATCH {
            # unable to write for some reason 
            return NoWrite;
        }
        # if we get here we must have successfully written to the dir 
        unlink $f;
        return CanWrite;
    }
    # if we get here the dir must not exist 
    return NoDir;
}
 
# test each of three directories by a non-root user 
my @dirs = (
    '/tmp',  # normally writable by any user 
    '/',     # writable only by root 
    '~/tmp'  # a non-existent dir in the user's home dir 
);
for @dirs -> $dir {
    my $stat = check-dir-status $dir;
    say "status of dir '$dir': $stat";
    if $stat ~~ CanWrite {
        say "  user can write to dir: $dir";
    }
}
# output 
#   status of dir '/tmp': CanWrite 
#     user can write to dir: /tmp 
#   status of dir '/': NoWrite 
#   status of dir '~/tmp': NoDir